Values   ::= WhiteSpace? ( Value ( WhiteSpace? Value )* )? WhiteSpace?

Value    ::= Number
           | OtherValue
           | AnyString
           | AnyWord
           | Path
           | Paren
           | Block

WhiteSpace
         ::= ( Space | Comment )+

Space    ::= CharSpace+

CharSpace
         ::= [#x0009#x000A#x000D#x0020#x007F]

Term     ::= #x0000 [#x0000-#xFFFFFF]*

Comment  ::= ';' [^#x0000#x000A#x000D]*

Number   ::= Integer
           | Decimal
           | Percent

OtherValue
         ::= Char
           | Date
           | Money
           | Pair
           | Time
           | Tuple
           | Literal

AnyString
         ::= Binary
           | Email
           | File
           | Issue
           | String
           | Tag
           | Url

AnyWord  ::= GetWord
           | SetWord
           | LitWord
           | Word
           | Refinement

Path     ::= AnyWord ( '/' ( Number | String | OtherValue | AnyWord ) )+

Paren    ::= '(' Values ')'

Block    ::= '[' Values ']'

Integer  ::= Sign? Digit ( Digit | ThousandSeparator )*

Decimal  ::= Sign? ( Digit ( Digit | ThousandSeparator )* ( DecimalExponent | DecimalSeparator ( Digit | ThousandSeparator )* DecimalExponent? ) | DecimalSeparator Digit ( Digit | ThousandSeparator )* DecimalExponent? )

Percent  ::= ( Integer | Decimal ) '%'

Money    ::= Sign? ( Alpha ( Alpha Alpha? )? )? '$' ( ( Digit | ThousandSeparator )+ '.'? | ( Digit | ThousandSeparator )* '.' ( Digit | ThousandSeparator )+ ) DecimalExponent

Char     ::= '#"' ( CharQuoted | CharEscaped ) '"'

Binary   ::= BinaryBase2
           | BinaryBase16
           | BinaryBase64

Email    ::= ':' ( CharEmail | ':' | '<' )* '@' ( CharEmail | ':' | '<' )*
           | CharEmail ( CharEmail | '<' )* '@' ( CharEmail | '<' )*

File     ::= '%' ( StringQuoted | CharFile* )

Issue    ::= '#' CharIssue?

String   ::= StringQuoted
           | StringBraced

Tag      ::= '<' CharTagFirst CharTag* '>'

Url      ::= CharUrlFirst CharUrl* ':' ( CharUrl | ':' | '/' | '@' )+

Date     ::= DateDate ( '/' Time DateZone? )?

Pair     ::= ( Integer | Decimal ) 'x' ( Integer | Decimal )

Time     ::= TimeHour ':' TimeMinute ( ':' TimeSecond )?

Tuple    ::= CharTuple CharTupleN CharTupleN ( CharTupleN ( CharTupleN ( CharTupleN ( CharTupleN ( CharTupleN ( CharTupleN CharTupleN? )? )? )? )? )? )?

Word     ::= WordSlash
           | WordCompare
           | CharSign
           | WordBase

GetWord  ::= ':' WordBase

SetWord  ::= WordBase ':'

LitWord  ::= "'" WordBase

Refinement
         ::= '/' ( Digit | CharWordFirst ) Word

Literal  ::= '#' Block

WordSlash
         ::= '/'+

WordCompare
         ::= '<' ( '<' | '>' | '=' )?
           | '>' ( '=' | '>' )?

CharWordFirst
         ::= [a-zA-Z?!.*&|=_~]

CharWord ::= CharWordFirst
           | [0-9+-']

WordBase ::= ( CharSign ( '.' "'"? )? | '.' "'"? )? CharWordFirst CharWord

Sign     ::= '+'
           | '-'

CharSign ::= Sign

Alpha    ::= [a-zA-Z]

Digit    ::= [0-9]

HexDigit ::= [0-9a-fA-F]

ThousandSeparator
         ::= "'"

DecimalSeparator
         ::= '.'
           | ','

DecimalExponent
         ::= 'e'
           | 'E' Sign? Digit+

StringQuoted
         ::= '"' ( CharQuoted | CharEscaped )* '"'

StringBraced
         ::= '{' ( CharBraced | CharEscaped | StringBraced )

CharQuoted
         ::= [^#x0000#x000A"^]

CharBraced
         ::= [^#x0000{}^]

CharEscaped
         ::= '^' ( '^' | '@' | '-' | '\' | '[' | ']' | '/' | '_' | [A-HK-Z] | '(' ( 'line' | 'tab' | 'page' | 'back' | 'null' | 'escape' | HexDigit HexDigit ( HexDigit HexDigit? )? ) ')' )

BinaryBase2
         ::= '2#{' Space? ( CharBase2 CharBase2 CharBase2 CharBase2 CharBase2 CharBase2 CharBase2 CharBase2 )* '}'

BinaryBase16
         ::= '16'? '#{' Space? ( CharBase16 CharBase16 )* '}'

BinaryBase64
         ::= '64#{' Space? CharBase64 CharBase64 CharBase64 CharBase64 ( CharBase64 CharBase64 CharBase64 [=] Space? | CharBase64 CharBase64 [=] Space? [=] Space? )? '}'

CharBase2
         ::= [0-1] Space?

CharBase16
         ::= HexDigit Space?

CharBase64
         ::= [0-9+/a-yA-Z] Space?

CharTuple
         ::= Digit
           | '0' Digit
           | Digit Digit
           | [0-1] Digit Digit
           | '2' ( [0-4] Digit | '5' [0-5] )

CharTupleN
         ::= '.' CharTuple

CharIssue
         ::= [^#x0000#x0009#x000A#x000D#x0020#x0022#x0028#x0029#x002F#x005B#x005D#x007B#x007D#x007F@$%:<>\#]

CharTagFirst
         ::= [^#x0000#x0009#x000A#x000D#x0020#x007F=<>"#x005D]

CharTag  ::= [^>#x0000]

CharUrlEscape
         ::= '%' CharHex CharHex

CharEmail
         ::= [^#x0000#x0009#x000A#x000D#x0020#x0022#x0028#x0029#x002F#x005B#x005D#x007B#x007D#x007F%@:<]
           | CharUrlEscape

CharUrlFirst
         ::= [a-zA-Z?!.*&|=_~]

CharUrl  ::= CharUrlFirst
           | [0-9'+-,]
           | CharUrlEscape

CharFile ::= [^#x0000#x0009#x000A#x000D#x0020#x0022#x0028#x0029#x005B#x005D#x007B#x007D#x007F%:@^]
           | CharUrlEscape
           | '^' ( '^' | '-' | '\' | '/' | '_' | [A-HK-Z] )

TimeHour ::= Sign Digit*
           | Sign? Digit+

TimeMinute
         ::= Sign? Digit Digit?

TimeSecond
         ::= Sign? ( Digit Digit? '.'? | ( Digit Digit? )? '.' Digit* )

DateZone ::= Sign Digit Digit? ':' ( '0' | '3' ) '0'

DateMonthName
         ::= 'Jan' ( 'u' ( 'a' ( 'r' 'y'? )? )? )?
           | 'Feb' ( 'r' ( 'u' ( 'a' ( 'r' 'y'? )? )? )? )?
           | 'Mar' ( 'c' 'h'? )?
           | 'Apr' ( 'i' 'l'? )?
           | 'May'
           | 'Jun' 'e'?
           | 'Jul' 'y'?
           | 'Aug' ( 'u' ( 's' 't'? )? )?
           | 'Sep' ( 't' ( 'e' ( 'm' ( 'b' ( 'e' 'r'? )? )? )? )? )?
           | 'Oct' ( 'o' ( 'b' ( 'e' 'r'? )? )? )?
           | 'Nov' ( 'e' ( 'm' ( 'b' ( 'e' 'r'? )? )? )? )?
           | 'Dec' ( 'e' ( 'm' ( 'b' ( 'e' 'r'? )? )? )? )?
           | '1' ( '0' | '1' | '2' )
           | '0'? Digit

DateDay  ::= '3' ( '0' | '1' | '2' )
           | ( '0' | '1' | '2' )? Digit

DateYear ::= digit ( digit ( digit ( digit digit? )? )? )?

DateDate ::= DateDay ( '-' | '/' ) DateMonth ( '-' | '/' ) DateYear
           | DateYear ( '-' | '/' ) DateMonth ( '-' | '/' ) DateDay